Sub ExportFc()
  Dim pDoc As IMxDocument
  Set pDoc = ThisDocument
  Dim pMap As IMap
  Set pMap = pDoc.FocusMap

  Dim pFLayer As IFeatureLayer
  Set pFLayer = pMap.Layer(0)

  Dim pFc As IFeatureClass
  Set pFc = pFLayer.FeatureClass

  'フィーチャクラスからFeatureClassNameを取得します。
  Dim pINFeatureClassName As IFeatureClassName
  Dim pDataset As IDataset
  Set pDataset = pFc
  Debug.Print pDataset.Name
  Set pINFeatureClassName = pDataset.FullName
  Dim pInDsName As IDatasetName
  Set pInDsName = pINFeatureClassName

  '選択セットを取得します。
  Dim pFSel As IFeatureSelection
  Set pFSel = pFLayer

  Dim pSelSet As ISelectionSet
  Set pSelSet = pFSel.SelectionSet

  '出力用の新規FeatureClassNameを作成します。
  Dim pFeatureClassName As IFeatureClassName
  Set pFeatureClassName = New FeatureClassName

  Dim pOutDatasetName As IDatasetName
  Set pOutDatasetName = pFeatureClassName

  pOutDatasetName.Name = "Export3"

  Dim pWorkspaceName As IWorkspaceName
  Set pWorkspaceName = New WorkspaceName

  pWorkspaceName.PathName = "c:\temp"
  pWorkspaceName.WorkspaceFactoryProgID = "esriCore.shapefileworkspacefactory.1"

  Set pOutDatasetName.WorkspaceName = pWorkspaceName

  pFeatureClassName.FeatureType = esriFTSimple
  pFeatureClassName.ShapeType = esriGeometryAny
  pFeatureClassName.ShapeFieldName = "Shape"

  'エクスポート
  Dim pExportOp As IExportOperation
  Set pExportOp = New ExportOperation
  pExportOp.ExportFeatureClass pInDsName, Nothing, _
  pSelSet, Nothing, pOutDatasetName, 0
End Sub