'Microsoft Scripting Runtimeライブラリへの参照設定が必要です

Sub TestFrequency()
  ' キーと値がペアとなったディクショナリを作成します
  ' キーは属性値で、ディクショナリの値は各属性値の頻度です
  Dim pDict As New Scripting.Dictionary
  Dim pMxDoc As IMxDocument
  Dim pFLayer As IFeatureLayer
  Dim pFSel As IFeatureSelection
  Dim pFCur As IFeatureCursor
  Dim lFld As Long
  Dim v As Variant
  Dim pFeat As IFeature

  Set pMxDoc = ThisDocument
  ' 最上位レイヤを取得します
  Set pFLayer = pMxDoc.FocusMap.Layer(0)
  Set pFSel = pFLayer

  If pFSel.SelectionSet.Count = 0 Then
    Set pFCur = pFLayer.FeatureClass.Search(Nothing, True)
  Else
    pFSel.SelectionSet.Search Nothing, True, pFCur
  End If

  lFld = pFCur.FindField("Name")　　'フィールド名を適宜変更します
  If lFld = -1 Then
    Debug.Print "NAMEフィールドが見つかりません"
    Exit Sub
  End If

  Set pFeat = pFCur.NextFeature
  Do While Not pFeat Is Nothing
    v = pFeat.Value(lFld)
    If pDict.Exists(v) Then
      pDict.Item(v) = pDict.Item(v) + 1
    Else
      pDict.Add v, 1
    End If
    Set pFeat = pFCur.NextFeature
  Loop

  ' list all counties and their frequency
  For Each v In pDict.Keys
    If pDict.Item(v) >= 1 Then
      Debug.Print v & ", " & pDict.Item(v)
    End If
  Next v
End Sub